Character not being displayed correctly

[ddebevec]

I have a one off REXX program that generates SYSIN cards. The problem that I'm encountering is the final ')' being dropped. I have tried different character masks i.e. queue"-START DB(" || part1 || ") SPACE(" || part2 || ")" but to no avail. I have included the REXX code, records and output. Can anyone tell me where I'm missing it? Thanks!

Code:

/* REXX */

inputFile = "SYSTMDD.REORG.FILE1"
outputFile = "SYSTMDD.REORG.FILE3"

"ALLOC FI(INFILE) DA("inputFile") SHR"
"ALLOC FI(OUTFILE) DA("outputFile") SHR"

"EXECIO * DISKR INFILE (STEM filedata. FINIS" /* Read file into array */

num_records = filedata.0 /* getnumber of records read */

SAY "Number of recorders read:" num_records

DO i = 1 TO num_records
record = filedata.i
record2 = translate(record, ' ', '.') /* Replace '.' with space */
parse var record2 part1 part2
queue"-STOP DB("part1") SPACE("part2")" <== this parentheses is lost
END

"EXECIO" queued() "DISKW outfile (FINIS"

"FREE FI(INFILE)"
"FREE FI(OUTFILE)"
EXIT

Source data:
AGMAILPD.AGADDRTS
AGMAILPD.AGAGNTTS
AGMAILPD.AGALTKTS
AGMAILPD.AGCBUSTS
AGMAILPD.AGCNTYTS

Output:
-STOP DB(AGMAILPD) SPACE(AGADDRTS
-STOP DB(AGMAILPD) SPACE(AGAGNTTS
-STOP DB(AGMAILPD) SPACE(AGALTKTS
-STOP DB(AGMAILPD) SPACE(AGCBUSTS
-STOP DB(AGMAILPD) SPACE(AGCNTYTS

[willy jensen]

Do a TRACE R before the loop to see what is really happening. The QUEUE statement is fine (I tested it), so one possible explanation is that the generated line is longer than the record length for the dataset that you write to, so that the records are truncated. Or in other words, the part2 variable might have a lot of spaces at the end. A quick way to verify this is to do a part2=STRIP(part2) before the QUEUE.

[ddebevec]

Adding the " part2=STRIP(part2)" fixed it. Thanks for your help.

[sergeyken]

Please, next time post it in such way.
Be polite to potential readers.

I have a one off REXX program that generates SYSIN cards. The problem that I'm encountering is the final ')' being dropped. I have tried different character masks i.e.

Code: Select all

queue"-START DB(" || part1 || ") SPACE(" || part2 || ")"

but to no avail. I have included the REXX code, records and output. Can anyone tell me where I'm missing it? Thanks!

Code:

Code: Select all

/* REXX */                                                                

inputFile  = "SYSTMDD.REORG.FILE1"                                        
outputFile = "SYSTMDD.REORG.FILE3"  
                                     
"ALLOC FI(INFILE) DA("inputFile") SHR"                                                                            
"ALLOC FI(OUTFILE) DA("outputFile") SHR"                                  
                                                                         
"EXECIO * DISKR INFILE (STEM filedata. FINIS" /* Read file into array */  
                                                                         
 num_records = filedata.0  /* getnumber of records read */                
                                                                         
SAY "Number of recorders read:" num_records  

DO i = 1 TO num_records                                              
 record = filedata.i                                                
 record2 = translate(record, ' ', '.') /* Replace '.' with space */  
 parse var record2 part1 part2                                      
 queue"-STOP DB("part1") SPACE("part2")"         <== this parentheses is lost                  
END          
                                                       
 "EXECIO" queued() "DISKW outfile (FINIS"
                                         
"FREE FI(INFILE)"                        
"FREE FI(OUTFILE)"                      
EXIT  

Source data:

Code: Select all

AGMAILPD.AGADDRTS
AGMAILPD.AGAGNTTS
AGMAILPD.AGALTKTS
AGMAILPD.AGCBUSTS
AGMAILPD.AGCNTYTS

Output:

Code: Select all

-STOP DB(AGMAILPD) SPACE(AGADDRTS
-STOP DB(AGMAILPD) SPACE(AGAGNTTS
-STOP DB(AGMAILPD) SPACE(AGALTKTS
-STOP DB(AGMAILPD) SPACE(AGCBUSTS
-STOP DB(AGMAILPD) SPACE(AGCNTYTS

[sergeyken]

Do a TRACE R before the loop to see what is really happening. The QUEUE statement is fine (I tested it), so one possible explanation is that the generated line is longer than the record length for the dataset that you write to, so that the records are truncated. Or in other words, the part2 variable might have a lot of spaces at the end. A quick way to verify this is to do a part2=STRIP(part2) before the QUEUE.

The correct solution should be like this:

Code: Select all

parse var record2 part1 part2 .

The dot as the last parameter placeholder eliminates all characters after the second parameter (in this example)

P.S.
One of the worst programming habits is: naming variables as "record2", "part1", "part2", "var23", "char27", "parm3", etc.

[willy jensen]

Re "parse var record2 part1 part2 ." only if the part2 variable is supposed to be a single word.
Personally I'd rather do

Code: Select all

queue "-STOP DB("part1") SPACE("strip(part2)")"

@ddebevec just a hint, if you check the RC after the "EXECIO" queued() "DISKW outfile (FINIS" command, you would have seen a RC=2, which tells you that record(s) have been truncated.

[sergeyken]

Personally I'd rather do without unneeded variables, and manipulations

Code: Select all

. . . . . . . . .
"EXECIO * DISKR INFILE ( FINIS" /* Read file into stack, no need for a stem */                                                                        
 num_records = queued()  /* get number of records read */                
                                                                         
SAY "Number of records read:" num_records  

/* re-fill the stack in a circle */
DO num_records             /* no need to use index */                                            
 parse pull part1 "." part2 .      /* no need for extra variables */                                
 queue "-STOP DB("part1") SPACE("part2")"   /* <== this parentheses is NOT lost now */              
END      
. . . . . . . . .