IBM Mainframe Forum

Posted: **Thu May 23, 2013 8:10 pm**

Hi all,

Need your help !!!. Is there a way to report all the Offline DASD devices specified on IODF while IPL from HCD ?? We can check manually thru HCD panel. But, if any utility that makes report will be helpful for us.

Kind regards,
Antony

Posted: **Thu May 23, 2013 9:57 pm**

Try this

Select all

OFFLINE CSECT
USING *,12
SAVE (14,12),,*
LR 12,15
LA 15,SAVEAREA
ST 15,8(,13)
ST 13,4(,15)
LR 13,15
OPEN (PRINT,OUTPUT)
LA 3,OUTLINE+4
LA 4,OUTLINE+78
NEXTUNIT UCBSCAN COPY,WORKAREA=UCBSWORK,UCBAREA=UCBSUCB, ?
DYNAMIC=YES,RANGE=ALL,DEVCLASS=DASD
LTR 15,15
BNZ DONE
TM (UCBSTAT-UCBOB)+UCBSUCB,UCBONLI
BO NEXTUNIT
CR 3,4
BL ADDUNIT
LA 0,OUTLINE
SR 3,0
STCM 3,B'0011',OUTLINE
PUT PRINT,(0)
LA 3,OUTLINE+4
ADDUNIT MVI 0(3),C' '
UNPK 1(5,3),(UCBCHAN-UCBOB)+UCBSUCB(3)
TR 1(4,3),HEXTAB
LA 3,5(,3)
B NEXTUNIT
DONE LA 0,OUTLINE
SR 3,0
STCM 3,B'0011',OUTLINE
PUT PRINT,(0)
CLOSE PRINT
FREEPOOL PRINT
L 13,4(,13)
RETURN (14,12),T,RC=0
SAVEAREA DC 9D'0'
PUSH PRINT
PRINT NOGEN
PRINT DCB DSORG=PS,MACRF=PM,DDNAME=SYSPRINT,RECFM=VBA,LRECL=125
POP PRINT
UCBSUCB DC XL48'0'
UCBSWORK DC XL100'0'
HEXTAB EQU *-C'0'
DC C'0123456789ABCDEF'
LTORG ,
OUTLINE DC AL2(*-*,0),CL121' '
PUSH PRINT
PRINT NOGEN
DCBD DSORG=QS,DEVD=DA
IEFUCBOB ,
POP PRINT
END OFFLINE

Posted: **Fri May 24, 2013 12:14 pm**

If you have a sufficient level of authorization this is a standard feature of ISMF (select option 2 (volume) select option 1 (dasd) and on the panel that is displayed there is an option to display offline volumes)

Posted: **Fri May 24, 2013 2:10 pm**

Hi Steve and Nevilh,

It worked fine. Thanks.

Kind regards,
Antony

IBM Mainframe Forum

HCD Report against offline device

HCD Report against offline device

Re: HCD Report against offline device

Re: HCD Report against offline device

Re: HCD Report against offline device